Für spirigwi

[Folker]

Moin Willy,

da Du zum einen meine Script-Experimente hier oft über den grünen Klee lobst und zum anderen etwas traurig warst, dass meine "Kulisse" explizit für AS 1.9.3 (OS X) geschrieben ist (siehe: http://www.fischer-bayern.de/phpBB2/viewtopic.php?p=4630#4630 ) habe ich keine Mühe gescheut! Ich habe meine Scheu vor OS 9 überwunden und das nochmals für Dich angepasst

Aber, da ich jetzt wieder am OS X sitze, kommt das Script unformatiert als reiner Text hier rein - viel Spaß beim "herumpröbeln"

(* ©2004 Folker Brandt, Versionen: 1.1De, OS 9.1, AS D1 1.6*)

-- Achtung: Zur Benutzung muss der Ordner AppleScriptObjects im Verzeichnis "Macintosh HD:Systemordner:Scripts:" natürlich vorher angelegt werden!!! In diesen Ordner werden dann die Script Objekte hineingelegt ...
property theObjPath : (((path to scripts folder) as string) & "AppleScriptObjects:")

--Objekte zur Textmanipulation im Verzeichnis "Macintosh HD:Systemordner:Scripts:AppleScriptObjects:"
property theScriptObjects : {"ScriptObj1.scpt", "ScriptObj2.scpt", "ScriptObj3.scpt"}

on run
try

-- Öffnen-Dialog
set oldDatei to (choose file with prompt "Datei wählen:" of type {"TEXT", "ttro"})

-- Pfad und Dateiname trennen
set {thedefaultlocation, theName} to get_pathParts(oldDatei as string)

-- alte Datei auslesen -> Optionen siehe read-Command der Standard Additions
set temp to get_Text(oldDatei)


--mittels repeat durch die Script-Objekte können wir versch. Manipulation durchführen und erhalten mehrere Dateien
repeat with i from 1 to (count items of theScriptObjects)

-- Neuen Dateinamen erhalten (Typ String)
set Tvar to get_newName(thedefaultlocation, theName, 0)

-- Neue Datei vorbereiten
set newDatei to (thedefaultlocation & Tvar)

(* Hier kann der Text der alten Datei manipuliert werden ... z.B Zeichentausch! Ideal z.B. über Script-Objekte *)

copy (load script (theObjPath & item i of theScriptObjects) as alias) to theScriptObj
set theNewText to theScriptObj's do_Convert(temp)

-- Text-Daten schreiben

set_Text(newDatei, theNewText)
end repeat

-- Fertig!
beep
display dialog "Datei \"" & theName & "\" wurde bearbeitet." buttons {"Yep"} default button 1 with icon 1 giving up after 60
on error errmsg number errnum
-- Falls oldDelim nicht mehr eingesetzt werden konnte, sicher ist sicher
set AppleScript's text item delimiters to {""}
if errnum is not -128 then
display dialog errmsg buttons {"Aargh..."} default button 1 with icon 0
end if
end try
end run

on get_Text(oldDatei)
-- alte Datei auslesen -> Optionen siehe read-Command der Standard Additions
-- das kann ja auch Absatzweise passieren o.ä.
return (read oldDatei)
end get_Text

on set_Text(newDatei, temp)
try
-- Neue Datei öffnen (dadurch anlegen!!!)
set theFileRef to (open for access (file newDatei) with write permission)

-- Neue Daten schreiben -> Optionen siehe read-Command der Standard Additions
write temp to theFileRef

-- Offene Datei schliessen
close access theFileRef
on error errmsg number errnum
try
-- open for access unbedingt abschließen
close access theFileRef
on error
-- Zur Sicherheit, falls über theFileRef das Schliessen versagt
try
close access (file newDatei)
end try
end try
--Fehler durchreichen
error errmsg number errnum
end try
end set_Text

-- Neuen Dateinamen errechnen
on get_newName(thedefaultlocation, theName, x)
repeat
-- falls die selbe Datei mehrmals verarbeitet werden soll
set x to (x + 1)
-- Abwärtskompatibel arbeiten -> max 31 Zeichen f. Dateinamen (27 + 4 f. ".txt")
if length of (theName & "_" & (x as string)) >= 28 then set theName to ((text items 1 thru 12 of theName & "…" & text items -1 thru (-14 + (length of ("_" & (x as string)))) of theName) as string)
-- checke ob der name schon existiert
if not (check_N(thedefaultlocation & theName & "_" & (x as string) & ".txt")) then exit repeat
end repeat
set theName to (theName & "_" & (x as string) & ".txt")
return theName
end get_newName

-- Neuer Dateiname schon benutzt?
on check_N(temp)
tell application "Finder" to return (file temp exists)
end check_N

-- Pfad und Dateiname mittels Vanilla AS trennen
on get_pathParts(oldDatei)
set {oldDelim, AppleScript's text item delimiters} to {AppleScript's text item delimiters, {":"}}
set thePath to (((text items 1 thru -2 of oldDatei) as string) & ":")
set theName to text item -1 of oldDatei
set AppleScript's text item delimiters to oldDelim
return {thePath, theName}
end get_pathParts

========================================

Script-Objekte:

-- Name: ScriptObj1.scpt

property the_oldChar : {"A", "B", "C", "D", "E", "F", "G", "H", "I", "J", "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", "U", "V", "W", "X", "Y", "Z", "Ä", "Ö", "Ü", "ß", "ä", "ö", "ü", " "} (* hier werden dann auch kleine Sonderzeichen berücksichtigt - deshalb nochmal ä,ö,ü am Ende der Liste - diese Liste ließe sich noch für weitere Sonderzeichen erweitern - allerdings müssen dann immer der Groß- und der Kleinbuchstabe als einzelnes List-Item berücksichtigt werden und in der Liste the_newChar doppelt aufgeführt sein. Auch alle weiteren Sonderzeichen lassen sich so bereinigen - aber stelle sicher, dass item x of the_oldChar immer mit item y of the_newChar korrespondiert - das die Listen gleiche Länge (Anzahl items) haben müssen versteht sich von selbst *)

property the_newChar : {"a", "b", "c", "d", "e", "f", "g", "h", "i", "j", "k", "l", "m", "n", "o", "p", "q", "r", "s", "t", "u", "v", "w", "x", "y", "z", "ae", "oe", "ue", "ss", "ae", "oe", "ue", "_"}

on do_Convert(DerString)
set {oldDelims, AppleScript's text item delimiters} to {AppleScript's text item delimiters, {""}}
considering case, white space, diacriticals, hyphens, expansion and punctuation
repeat with i from 1 to (count items of the_oldChar)
if (item i of the_oldChar is in DerString) then
set AppleScript's text item delimiters to {item i of the_oldChar}
set DerString to (text items of DerString)
set AppleScript's text item delimiters to {item i of the_newChar}
set DerString to (DerString as string)
end if
end repeat
end considering
set AppleScript's text item delimiters to oldDelims
return DerString
end do_Convert

==================

-- Name: ScriptObj2.scpt


property the_oldChar : {"a", "b", "c", "d", "e", "f", "g", "h", "i", "j", "k", "l", "m", "n", "o", "p", "q", "r", "s", "t", "u", "v", "w", "x", "y", "z", "ä", "ö", "ü", "_"}

property the_newChar : {"A", "B", "C", "D", "E", "F", "G", "H", "I", "J", "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", "U", "V", "W", "X", "Y", "Z", "Ä", "Ö", "Ü", " "}


on do_Convert(DerString)
set {oldDelims, AppleScript's text item delimiters} to {AppleScript's text item delimiters, {""}}
considering case, white space, diacriticals, hyphens, expansion and punctuation
repeat with i from 1 to (count items of the_oldChar)
if (item i of the_oldChar is in DerString) then
set AppleScript's text item delimiters to {item i of the_oldChar}
set DerString to (text items of DerString)
set AppleScript's text item delimiters to {item i of the_newChar}
set DerString to (DerString as string)
end if
end repeat
end considering
set AppleScript's text item delimiters to oldDelims
return DerString
end do_Convert


==================

-- Name: ScriptObj3.scpt


(* Speziell für alle FileMaker -
Bei Exporten als Text mit Tab hat man manchmal folgende Wünsche:

Tab soll Return werden,
Zeilenumbruch im Textfeld soll auch Return werden, diese kommen aus FMP mit ASCII 11
Trennzeichen zw. Wiederholungen in Wiederholfelder kommen als ASCII 29 aus FMP - sollen Tab werden!
*)

property the_oldChar : {(ASCII character 9), (ASCII character 11), (ASCII character 29)}

property the_newChar : {(ASCII character 13), (ASCII character 13), (ASCII character 9)}


on do_Convert(DerString)
set {oldDelims, AppleScript's text item delimiters} to {AppleScript's text item delimiters, {""}}
considering case, white space, diacriticals, hyphens, expansion and punctuation
repeat with i from 1 to (count items of the_oldChar)
if (item i of the_oldChar is in DerString) then
set AppleScript's text item delimiters to {item i of the_oldChar}
set DerString to (text items of DerString)
set AppleScript's text item delimiters to {item i of the_newChar}
set DerString to (DerString as string)
end if
end repeat
end considering
set AppleScript's text item delimiters to oldDelims
return DerString
end do_Convert
_________________
Gruß,
Folker Brandt
=============================
Systemberatung · Datenbanken · Webdesign

[spirigwi]

[Folker]

Hallo Willy,

das war so gedacht wie geschrieben - Script-objecte sind kompilierte Scriptdateien. Jedes Objekt ist eine Datei! Also nicht die 3 Objekte in einem Script zusammenfügen.

Man hätte das ganze natürlich ohne Repeat-Loop machen können und nutzt nur 1 Script-Objekt, dann aber eher als Aufbewahrung versch. Properties und Handler. Nur ging es mir im obigen Beispiel halt um das Schema - ist ja eigentlich eine sinnfrei Spielerei.

Ich habe es extra nochmal auf dem 9er Rechner probiert - mein Text konnte anstandslos im IE kopiert werden, in ein AS-Fenster eingesetzt werden und kompiliert werden - kein error kreuzte den Weg!

Ich würde es an Deiner Stelle erst einmal belassen wie von mir geschrieben und dann mal gucken was wo und warum passiert - dabei hilft wie so oft ein 'tell me to log WasauchimmerVariable' - auch das Eventprotokoll ist meist aufschlußreich ...

Aber Deine Interpretation werde ich mir später in Ruhe genauer anschauen - bis dahin "happy scripting"!
_________________
Gruß,
Folker Brandt
=============================
Systemberatung · Datenbanken · Webdesign

[spirigwi]

"jetzt kann ich auch die Tiger aus dem Käfig lassen"
on do_Convert(DerString)
   set {oldDelims, AppleScript's text item delimiters} to {AppleScript's text item delimiters, {""}}
   considering case, white space, diacriticals, hyphens, expansion and punctuation
      repeat with i from 1 to (count items of the_oldChar)
         if (item i of the_oldChar is in DerString) then
            set AppleScript's text item delimiters to {item i of the_oldChar}
            set DerString to (text items of DerString)
            set AppleScript's text item delimiters to {item [c olor=#ED181E]i[/color] of the_newChar}
            set DerString to (DerString as string)
         end if
      end repeat
   end considering
   set AppleScript's text item delimiters to oldDelims
   return DerString
end do_Convert

und zwischenzeitlich ging mir der zwanziger(Wert weit unter dem 20 cent EURO) auch noch runter wie man die OLDIES_handlers halt einzeln betrachten muss. Alles o.B Folker, nochmals vielen dank für soviel Mühe
_________________
 Skript-Fan => ein � -Fan =>Scr¿¿-KongFuSius_Kurpfusius

[spirigwi]

Folker nur noch eine Erklärung aus der Froschperspektive um dir möglichst minimal Zeit zu klauen :
natürlich würde ich es in meinem Stadium nicht wagen bei so komplexen Skripten eine eigene

[Folker]

Hallo Willy,

nein nicht ernsthaft eine Antwort - zumal nach einer Flasche Rioja ....

Interpretaion - ja doch immer - nur so geht es!!!! - Ja , mit meinen 44 J. und 4 kiddies um mich herum habe ich gelernt und lerne noch immer: Die eigene Interpretation, welche selbtsverständlich historisch permanent entwicklungsfähig ist, ist durch nichts zu ersetzen.

Verbraucher? Nein! - Es geht doch mehr um "Lernende"!

Sorry - das mit dem umkopieren ist natürlich eine Krücke...
Das 2. Script-Object will net - hmmmmm ........
promt "Welch rudimentäre Informationsgesellschaft" buttons {"AAAARGHHHH...} default button 1

Isch denke, Du kannscht mir ein Emil (Steinberger ) schenden - Du bekommst die Script und Ordner und Script-Objects via Emil gesendet - von nem 9er Rechner ... nix mit rauskopieren und et geht nix
_________________
Gruß,
Folker Brandt
=============================
Systemberatung · Datenbanken · Webdesign

[spirigwi]