alle dateien in allen ordnern

[mike]

tag zusammen.

hat jemand ein skript das folgendes macht:

alle dateien in allen unterordnern aller unterordner auswählen

bei allen ausgewählten dateien das änderungsdatum aktualisieren


??

oder wenigstens eine anregung ??

[Snow]

Anregung kann ich bieten:

Schau dir mal meinen Workshop-Artikel "Rekursive Handler" an, und ändere das Skript etwas ab. Du musst eigentlich nur die Anweisung an den Finder abändern. Im Beipspiel werden die Dateien geschützt bzw. der Schutz von bereits geschützten Dateien aufgehoben. Diesen Teil musst du nur ersetzen mit den Anweisungen zum modifizieren des Änderungsdatums.
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[mike]

das ist schon mal sehr hilfreich - herzlichen dank

und wie ändert man änderungsdatum/zeit irgendeiner datei auf dem mac?

[Snow]

OK, dann kommt hier halt der Rest der Anregung:

Den letzten Teil des Beispiel-Skripts austauschen gegen:

-- Dateien werden bearbeitet
on ProcessIt(theFile)
tell application "Finder"
set modification date of theFile to current date
end tell
end ProcessIt
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[mike]

hallo snow
zunächst herzlichen dank für deine präzise anregung; bin wieder mal beeindruckt.

jetzt besteht nur noch folgendes problem:

das skript steigt die ordnerhierarchie nicht hinab, sondern bricht beim ersten ordner ohne fehlermeldung ab. hätteste vielleicht noch einen tipp ?

in unix würde ich schreiben:

find . -exec touch {} ";"

ist es die möglichkeit, dass die angelegenheit auf mac derart kompliziert ist ?

gruss

[Snow]

Hallo Mike,

welche OS Version, welche AppleScript Version?

Probier mal folgende Variante des Skripts:

-- Run-Handler zum debuggen
on run
   set theFileList to (choose folder) as list
   repeat with theFile in theFileList
      File_or_Folder(theFile)
   end repeat
end run


on open theFileList -- Per Drag & Drop wird
   -- eine Liste mit Referenzen an das Skript übergeben
   repeat with theFile in theFileList
      File_or_Folder(theFile)
   end repeat
end open


-- Prüfung, ob es sich um einen Ordner oder
-- eine Datei handelt
on File_or_Folder(theObject)
   try
      tell application "Finder" to set itemList to items of theObject as alias list
   on error
      tell application "Finder" to set itemList to items of theObject as alias as list
   end try
   repeat with anItem in itemList
      if (anItem as text) ends with ":" then
         File_or_Folder(anItem as alias)
      else
         ProcessIt(anItem as alias)
      end if
   end repeat
end File_or_Folder


-- Dateien werden bearbeitet
on ProcessIt(theFile)
   tell application "Finder"
      set modification date of theFile to current date
   end tell
end ProcessIt


Da habe ich den Befehl 'info for' mal weggelassen und dafür einen anderen Weg gewählt. Mit 'info for' gab's während der letzten Versionen immer ein hin und her. Deshalb vermute ich, dass dies auch der Fehler ist.
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[mike]

einsame spitze.

der einzige kleine fehler, den das skript jetzt noch hat:

das änderungsdatum der ORDNER wird nicht gesetzt. muss aber.

[mike]

habs unterdessen gschafft.


nochmal vielen herzlichen dank !

[mike]

hallo snow, da bin ich wieder.

ist es auch möglich, mit " set creation date " oder so nachträglich das erzeugungsdatum einer datei zu ändern ?

bei mir gehts jedenfalls nicht ...

[Snow]