Attribut 'Geschützt' entfernen

[cosi]

hallo

wie kann ich per applescript das attribut 'geschützt' von dateien entfernen? habe zig as-verzeichnisse durchsucht aber nichts gefunden, das mir weiterhilft.
danke für jede hilfe.

gruss, ph. cosi

[Snow]

Hallo cosi,

die gesuchte Eigenschaft ist "locked". Wenn du das Befehlsverzeichnis des Finders ansiehst, wirst du entdecken, dass die Klasse "file" Eigenschaften von "item" erbt.

Bei "item" findest du dann die gesuchte Eigenschaft. "locked" kann man dann per Skript auf "true" oder "false" setzen.

Beispiel, das als Droplet oder Applet funktioniert und Ordnerhierarchien dabei abarbeitet:

(* Dieses Skript schützt ungeschützte Dateien und
hebt den Schutz von geschützten Dateien auf.
© 2003 by Fischer-Bayern
http://fischer-bayern.de/applescript/
snow@fischer-bayern.de
*)



-- Run-Handler zum debuggen
on run
   set theFileList to (choose folder) as list
   repeat with theFile in theFileList
      File_or_Folder(theFile)
   end repeat
end run


on open theFileList -- Per Drag & Drop wird
   -- eine Liste mit Referenzen an das Skript übergeben
   repeat with theFile in theFileList
      File_or_Folder(theFile)
   end repeat
end open


-- Prüfung, ob es sich um einen Ordner oder
-- eine Datei handelt
on File_or_Folder(theObject)
   try
      tell application "Finder" to set itemList to items of theObject as alias list
   on error
      tell application "Finder" to set itemList to items of theObject as alias as list
   end try
   repeat with anItem in itemList
      if (anItem as text) ends with ":" then
         ProcessIt(anItem as alias)
      else
         ProcessIt(anItem as alias)
      end if
   end repeat
end File_or_Folder


-- Dateien werden bearbeitet
on ProcessIt(theFile)
   tell application "Finder"
      if locked of theFile = false then
         set locked of theFile to true
      else
         set locked of theFile to false
      end if
   end tell
end ProcessIt


Die eigentliche Arbeit findet im letzten Handler (ProcessIt) statt.
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[cosi]

...super. danke für die prompte anwort.

gruss, cosi