iTunes - auf Remote Computer starten

[Snow]

Dieses Skript startet iTunes auf einem Netzwerkrechner. Die IP-Adresse des Zielrechners muss natürlich angepasst werden.

Code:

global u
set u to machine "eppc://USER:PASSWORT@192.0.1.2"

tell application "Finder" of u
    using terms from application "Finder"
        set tApps to name of every process whose visible is true
        if tApps does not contain "iTunes" then
            set Pfad to application file id "hook"
            try
                open Pfad
                my PlayTunes()
            on error errmsg
                display dialog errmsg
            end try
        else
            my PlayTunes()
        end if
    end using terms from
end tell

on PlayTunes()
    tell application "iTunes" of u
        using terms from application "iTunes"
            try
                set tState to player state
                if tState is playing then
                    stop
                else
                    play some track of playlist 1
                end if
            on error errmsg
                display dialog errmsg
            end try
        end using terms from
    end tell
end PlayTunes

Anmerkung:

Unter OS 9 muss im Kontrollfeld "File Sharing" - Registerkarte "Start/Stop" der Punkt "Programmverbindungen ein" aktiviert sein. Auch sollte bei der kleinen Checkbox "Clients greifen auf Programmverbindungen per TCP/IP zu" ein Haken gesetzt sein.

Unter OS X:
Systemeinstellungen - Sharing - Entfernte AppleEvents
Und evtl. ein Haken bei "Events von OS 9 zulassen"
_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com

[Snow]

Anmerkung zum Skript unter Tiger:

Die Prüfung der laufenden Prozesse führt dazu, dass das Skript respektive der Skripteditor "unerwartet" beendet wird.

Diese Überprüfung muss nun an das Programm "System Events" addressiert werden.

global u
set u to machine "eppc://USERNAME:PASSWORT@192.0.1.1"

tell application "System Events" of u
    using terms from application "System Events"
        set tApps to name of every process whose visible is true
    end using terms from
end tell
tell application "Finder" of u
    using terms from application "Finder"
        if tApps does not contain "iTunes" then
            set Pfad to application file id "hook"
            open Pfad
            my PlayTunes()
        else
            my PlayTunes()
        end if
    end using terms from
end tell

_________________
Peter
-
Fischer-Bayern.de|Shadetreemicro.com