AppleScript unter OS 9.1

[langanki]

Hallo,

kann mir jemand bei AppleScript weiterhelfen?

Es geht um folgendes:

Habe eine ISDN-Rechner, G3 beige, MacOS 9.1 und möchte folgendes erreichen:

Wenn sich der ISDN-Eingangsordner verändert, d.h. eine neue Datei hinzu kommt, soll Outlook Express aufgehen und eine E-Mail mit einem Standardtext an eine bestimmte Adresse verschickt werden. Danach soll Outlook Express wieder beendet werden.

Eigentlich gar nicht so schwer, oder? Hab aber leider gar keine Ahnung von AppleScript.

Für Hilfe bin ich sehr dankbar.

Grüße Thomas

[herkules]

hi!
probier mal das unten stehende script. hab ich mal rasch geschrieben, kann also sicher noch verfeinert werden. für den anfang sollte es aber sicher reichen.
voraussetzung ist einzig "Outlook Express" und der isdn-ordner muss vorhanden sein... ausserdem gilts noch den einen oder anderen wert anzupassen.
achtung: wenn du das script absicherts, dann mit der option "Stay Open". ansonsten schliesst sich das programm sogleich wieder
viel spass beim pröbeln

****************************************

-----------------------
-- V A R I A B E L N --
-----------------------
property WarteZeit : 2
property IsdnOrdner : ""
property IsdnZaehlerNeu : 0
property IsdnZaehlerAlt : 0




-- Isdn-Ordner angeben
set IsdnOrdner to "MacXY:Desktop Folder:IsdnEingang:" as string

-- Isdn-Liste auslesen
|IsdnListeNeu|()

-- Zaehler gleichsetzten (fuer Programm-Start)
set IsdnZaehlerAlt to IsdnZaehlerNeu


-- Schlaufe starten
on idle

-- Mail versenden, wenn neues File in Ordner
if IsdnZaehlerNeu > IsdnZaehlerAlt then

-- Mail versenden
|MailVersenden|()

-- Isdn-Liste auslesen
|IsdnListeNeu|()

-- Zaehler gleichsetzten
set IsdnZaehlerAlt to IsdnZaehlerNeu

else

-- Wenn IsdnZaehlerNeu kleiner als IsdnZaehlerAlt, ist ein Ordner entfernt worden
if IsdnZaehlerNeu < IsdnZaehlerAlt then

-- Zaehler gleichsetzten (fuer Programm-Start)
set IsdnZaehlerAlt to IsdnZaehlerNeu
else
-- Isdn-Liste auslesen
|IsdnListeNeu|()

end if
end if

-- nach WarteZeit wiederholen
return WarteZeit

end idle




---------------------------
-- S U B R O U T I N E N --
---------------------------

-- Isdn-Liste-Neu abfuellen
--*************************
on |IsdnListeNeu|()

set IsdnOrdnerListeNeu to (list folder IsdnOrdner without invisibles)
set IsdnZaehlerNeu to length of IsdnOrdnerListeNeu

end |IsdnListeNeu|




-- Mail versenden
on |MailVersenden|()

tell application "Outlook Express"

-- aktivieren
activate
-- Mail zusammensetzen
set Mail_Msg to (make new outgoing message with properties {recipient:"name@host.de", subject:"isdn-test", content:"es ist etwas neues im isdn-eingang!"})
-- Mail versenden
send Mail_Msg

end tell

end |MailVersenden|

******************************
_________________
gruss christos;-)

[spirigwi]